# examen junio 2014

1.- Formular 

ATP + AMP <---> 2*ADP

con ATP(0)=2, AMP(0)=0, ADP(0)=8 y k1=2, k2=1

Solución:

a) Llamo a las concentraciones (mM) tras t minutos de cada elemento

A(t) = ATP, X(t)= AMP, B(t)= ADP, es decir tenemos

A + X <---> 2*B

Este modelo de choques se traduce en la ED

X'(t) = -k1*A(t)*X(t) + k2*B(t)^2

donde 

A(0)-A(t) = X(0)-X(t) = [B(t)-B(0)]/2

Usando los datos iniciales obtenemos

A(t) = 2+X(t),   B(t) = 8-2*X(t)

y la ecuacion diferencial queda

X' = -2*(2+X)*X + (8-2*X)^2 = ... = 2*(X-16)*(X-2)

-2*(2+X)*X + (8-2*X)^2;

expand(%);

factor(%);

b) De aquí se ven las soluciones de equilibrio X_eq=16, X_eq=2.
La primera no tiene sentido (no puede haber más de 8 moles de X),
por tanto

X_eq = 2, A_eq = 4, B_eq = 4

Las gráficas de A(t), B(t), X(t) se esbozan fácilmente con el dato inicial
(yo lo haré con Maxima luego).

c) Para resolver la ED a mano hay que separar variables y resolver 
la integral racional que sale

dx/[(x-16)*(x-2)] = 2*dt

Desarrollando en fracciones simples tendremos

1/[(x-16)*(x-2)];= 1/14*[ 1/(x-16) - 1/(x-2) ]

1/[(x-16)*(x-2)];

partfrac(%, x);

Por tanto la ED la podemos resolver a mano con

1/14 * ln[(x-16)/(x-2)] = 2*t + C

o bien 

ln[(16-x)/(2-x)] = 28*t + C

Como X(0)=0, tenemos C=ln 8.

Por último piden t_{0.5}, es decir t tal que x= 1 (mitad de x_eq)

ln 15 = 28*t + ln 8  --> t=1/28*ln(15/8)

sale t= 0.0224 min = 1.35 seg

1/28*log(15/8),numer;

%*60;

de forma similar se halla t_{0.9}, es decir t tal que x= 1.8 (el 90% de x_eq)

ln( 14.2/0.2)= 28*t + ln 8

t= 1/28*ln(71/8)

es decir t_{0.9} = 0.078 min = 4.7 seg

 1/28*log(71/8),numer;

%*60;

OPCIONAL: se podia resolver la ED con Maxima y responder a b)-c) mirando la gráfica

ed1: 'diff(x,t)= 2*(x-16)*(x-2);

ode2(ed1, x, t);

logcontract(%);

solve([%], [x]);

ic1(%, t=0, x=0);

X(t):=(16*%e^(28*t)-16)/(8*%e^(28*t)-1);
A(t):=2+X(t);B(t):=8-2*X(t);

wxplot2d([A(t), X(t), B(t)], [t,0,.15],[legend, ATP, AMP, ADP])$

find_root(X(t)=1, t, 0, 1);

find_root(X(t)=1.8, t, 0, 1);

EJERCICIO 2: desintegración 117Cd --> 117In --> 117Sn

Nos dan el sistema 

x' = -0.3* x
y' = 0.3*x -y

con x(0)=1'4, y(0)=0

a) semividas de los productos: 

usar la formula T=ln(2)/k, donde k=tasa desintegración

Como k1=0.3 y k2=1 tenemos

T1= 2'3 horas  = 2 horas 19 min aprox 
T2= 0'69 horas = 42 min aprox

if numer#false then numer:false else numer:true;

log(2)/0.3;log(2);

.310490601866484*60;0.69314718055995*60;

b) Resolver el sistema: se puede resolver a mano

- autovalores: -0.3, -1 (se ven a ojo pq matriz es triangular)
- autovectores: se calculan a mano p1=[0'7 0'3], p2=[0 1]
- Solucion:

x(t) = c1*0.7 *exp(-0.3*t) 
y(t) = c1*0.3*exp(-0.3*t) +c2*exp(-t)

usando el dato inicial sale c1=2, c2=-0.6 y 

x(t) = 1.4 *exp(-0.3*t) 
y(t) = 0.6*[ exp(-0.3*t) - exp(-t) ]

Abajo llegamos a la misma fórmula con maxima

ed1:'diff(x(t),t)= -0.3*x(t);
ed2:'diff(y(t),t)=0.3*x(t)-y(t);

desolve([ed1,ed2],[x(t),y(t)]);

ev(%, x(0)=1.4,y(0)=0);

x(t):=1.4*%e^(-0.3*t);y(t):=0.6*%e^(-0.3*t)-0.6*%e^(-t);

wxplot2d([x(t),y(t)], [t,0,10],[legend,"117Cd", "117In"],[xlabel,"t (horas)"],
[ylabel,gramos])$

c) Piden y(t) máxima, a ojo se ve un poco antes de t=2

diff(y(t),t,1);

find_root(0.6*%e^(-t)-0.18*%e^(-0.3*t)=0, t, 0, 2);

y(%);

.719961149037051*60;

por tanto y(t) es máximo tras 1'72 horas = 43 min (aprox), alcanzando los 0.25 gramos.
Claramente x(t) e y(t) nunca se igualan 

d) si se añaden 3 gr/hora de x(t) el sistema queda

x' = -0.3* x + 3
y' = 0.3*x -y

y por tanto

x_eq = 3/0.3= 10 gr
y_eq = 0.3*x_eq = 3 gr.

EJERCICIO 3: circuito
V'' + 2*V+ + 122*V = 0 

ed:'diff(V,t,2)+2*'diff(V,t)+122*V=0;

ode2(ed, V, t);

bc2(%, t=0, V=220, t=%pi/2, V=-220*exp(-%pi/2));

V(t):=%e^(-t)*(220*sin(11*t)+220*cos(11*t));

wxplot2d([V(t)], [t,0,5])$

b) en la gráfica vemos a ojo que se anula la primera vez cuando t =0'21 aprox
Veamos el valor exacto

find_root(V(t)=0, t, 0, 0.25);

También se puede hacer a mano: V(t)= 0 si tan(11*t)=-1,
y esto ocurre cuando 11*t = -pi/4 + 2*pi= 3*pi/4,
es decir t=3*pi/44

3*%pi/44,numer;

c) conductividad tq frecuencia oscilacion sea 5

V'' +2*V' + c*V=0

Los autovalores son -1 +- sqrt( 1-c )

x^2+2*x+c=0;

solve([%], [x]);

Por tanto necesito sqrt(1-c) = sqrt (-25),
es decir c-1=25, y por tanto c=26.

4) MOVIMIENTO PLANETARIO

x' = v
v' = (1-x)/x^3

a) La solucion de equilibrio es x_eq = 1, v_eq = 0.

- Diagrama de fases: dibujandolo parece que las soluciones podrian girar
entorno al equilibrio 

- Estabilidad: calculando la matriz derivada vemos que sale

[0 , 1; (3*x-4)/x^4, 0] = [0 1; -1 0 ]

que tiene autovalores +-i. Por tanto caso de DUDA

b) Dibujamos la solución con ordenador

- usando plotdf

plotdf([y,(1-x)/x^3],[x,0.1,5],[y,-2,2],
[trajectory_at,1,1],
[direction,forward],[nsteps,1000],[versus_t,1]);

pinchando se observan soluciones periodicas entorno al pto de equilibrio.
Probando con datos iniciales x(0)=1, v(0)=a, se observa:

- las soluciones son periódicas al menos  cuando a<0'9,
y dejan de serlo para a > 0.9 (aprox)

C:\verso\curso_UM\biotec2014\examen\fig1_exam.jpg

Nota: Para que esta figura quede pegada (sin tener que salvarla aparte),
se  puede usar el comando wxdrawdf:

dibujamos  las curvas para a=1, a=0.5, a=  0.8

load(drawdf);

wxdrawdf([y,(1-x)/x^3],[x,0.1,5],[y,-2,2],
[trajectory_at,1,1],
[direction,forward],[nsteps,1000]);

wxdrawdf([y,(1-x)/x^3],[x,0.1,5],[y,-2,2],
[trajectory_at,1,0.5],
[direction,forward],[nsteps,1000]);

wxdrawdf([y,(1-x)/x^3],[x,0.1,5],[y,-2,2],
[trajectory_at,1,0.8],
[direction,forward],[nsteps,1000]);